企业或网吧环境下，设置Windows桌面的EDGE快捷方式禁止修改的方法教程

在企业或网吧环境下，edge会自动更新，更新以后会覆盖掉我们设置的首页网址，所以我们可以让edge桌面的快捷方式不可修改，这样就能达到我们想要设置为自己想要的网址的目的了。

命令行如下：

@echo off
chcp 936 >nul 2>&1
:: 黑色底色 + 亮绿色字体
color 0A
:: 必须管理员权限运行
fltmc filters >nul 2>&1 || (echo 请右键选择【以管理员身份运行】& pause & exit)

echo.
echo ================= Edge快捷方式部署工具 =================
echo 1 = 创建可修改快捷方式（不勾选只读，后续可改参数）
echo 2 = 创建锁定只读快捷方式（防止Edge更新重置启动网址）
echo ========================================================
set "choice="
set /p "choice=请输入数字 1 或 2 并回车："
if not "%choice%"=="1" if not "%choice%"=="2" (echo 输入错误，程序退出 & pause & exit)

echo.
echo === 开始清理旧快捷方式（先取消只读才能删除） ===
:: 公共桌面 取消只读+删除
attrib -r "C:\Users\Public\Desktop\Microsoft Edge.lnk" >nul 2>&1
del /f /q "C:\Users\Public\Desktop\Microsoft Edge.lnk" >nul 2>&1
:: 当前用户桌面 取消只读+删除
attrib -r "%USERPROFILE%\Desktop\Microsoft Edge.lnk" >nul 2>&1
del /f /q "%USERPROFILE%\Desktop\Microsoft Edge.lnk" >nul 2>&1
:: 当前用户个人开始菜单 取消只读+删除
attrib -r "%APPDATA%\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk" >nul 2>&1
del /f /q "%APPDATA%\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk" >nul 2>&1
:: 全局公用开始菜单 取消只读+删除
attrib -r "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk" >nul 2>&1
del /f /q "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk" >nul 2>&1

echo === 创建桌面快捷方式 ===
powershell -Command "$s=(New-Object -COM WScript.Shell).CreateShortcut([Environment]::GetFolderPath('Desktop')+'\Microsoft Edge.lnk');$s.TargetPath='C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe';$s.Arguments='https://www.baidu.com';$s.WorkingDirectory='C:\Program Files (x86)\Microsoft\Edge\Application';$s.Description = '浏览 Web'; $s.Save()" >nul 2>&1

echo === 创建【全局公用开始菜单】快捷方式 ===
powershell -Command "$shell = New-Object -COM WScript.Shell;$lnkPath='C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk';$s=$shell.CreateShortcut($lnkPath);$s.TargetPath='C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe';$s.Arguments='https://www.baidu.com';$s.WorkingDirectory='C:\Program Files (x86)\Microsoft\Edge\Application';$s.Description = '浏览 Web'; $s.Save()" >nul 2>&1

:: 根据选择设置只读
if "%choice%"=="2" (
    echo 已开启只读锁定，Edge更新不会覆盖参数
    attrib +r "%USERPROFILE%\Desktop\Microsoft Edge.lnk"
    attrib +r "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk"
) else (
    echo 快捷方式为可编辑状态，无只读锁定
    attrib -r "%USERPROFILE%\Desktop\Microsoft Edge.lnk"
    attrib -r "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk"
)

echo.
echo 操作完成，2秒后自动退出...
ping -n 2 127.0.0.1 >nul 2>&1
exit

保存为edge.bat或edge.cmd运行都可以，保存的时候记得选择ansi编码，WIN10以上都默认是UTF8了。

你也可以直接下载成品:

通过网盘分享的文件：Edge快捷方式部署工具.rar
链接: https://pan.baidu.com/s/1TN5MqLm8hmPXyUaLFo2_Aw?pwd=ghxy 提取码: ghxy 复制这段内容后打开百度网盘手机App，操作更方便哦

『来自123云盘用户im2828.com的分享』Edge快捷方式部署工具.rar
链接：https://1816706521.share.123pan.cn/123pan/HMU6Vv-sCvGd?pwd=Si9A#
提取码：Si9A

下载:https://wwapm.lanzouu.com/inG4c3sjqlad 密码:bd5b